@echo off
REM ZLstart.bat by DJ9ZL --- V2020-06-11
REM start/end digital modes with CAT and logging, Windows10/64, IC706/IC7300
REM V2017-03-21 created DJ9ZL
REM V2017-07-13 added SIM-PSK
REM V2017-07-27 added time-delay
REM V2017-11-10 removed old stuff
REM V2019-03-08 JS8Call added
REM V2020-02-18 ROS and FSQ added
REM -------------------------------------------

SETLOCAL EnableExtensions
CHCP 1252
mode con:cols=96 lines=24
echo ===========================  ZLstart - startup digital modes  ============================="
set /p mode="Mode JS8[0], FT8[1], DRM780[2], SIM31[3], EasyPal[4], ROS[5], FSQ[6], HRDlog[7], Kill[k]: "
if "%mode%" EQU "0" goto 8
if "%mode%" EQU "1" goto 1
if "%mode%" EQU "2" goto 2
if "%mode%" EQU "3" goto 3
if "%mode%" EQU "4" goto 4
if "%mode%" EQU "5" goto 5
if "%mode%" EQU "6" goto 6
if "%mode%" EQU "7" goto 7
if "%mode%" EQU "k" goto kill
echo Unknown Mode !!
echo ===============
pause
goto done

REM ----------- JT9/JT65/FT8 -------------------
:1
call :init
call :check_running "wsjtx.exe"
If /I %RUNNING%==False (
	start "JT9" /D "C:\Program Files (x86)\wsjtx" /B /HIGH "C:\Program Files\wsjtx\bin\wsjtx.exe"
	timeout /t 3 /Nobreak
)
call :check_running "JTAlert.exe"
If /I %RUNNING%==False start "" /B /REALTIME "C:\Program Files (x86)\HamApps\JTAlert\JTAlert.exe" /wsjtx
goto done

REM ----------- DRM780 -------------------
:2
call :init
call :check_running "Digital Master.exe"
If /I %RUNNING%==False start "DRM780" /D "C:\Program Files (x86)\HRD Software, LLC\Ham Radio Deluxe" /B /REALTIME "C:\Program Files (x86)\HRD Software, LLC\Ham Radio Deluxe\Digital Master.exe"
goto done

REM ----------- SIM-PSK -------------------
:3
call :init
call :check_running "sim_psk.exe"
If /I %RUNNING%==False start "sim_psk" /D "%HOMEPATH%\jmprogs\hamradio\SIM-31" /B /NORMAL "%HOMEPATH%\jmprogs\hamradio\SIM-31\sim_psk.exe"
goto done

REM ----------- EasyPal -------------------
:4
call :init
call :check_running "EasyPal.exe"
If /I %RUNNING%==False start "EasyPal" /D "C:\Program Files\EasyPal" /B /NORMAL "C:\Program Files\EasyPal\EasyPal.exe"
goto done

REM ----------- ROS -------------------
:5
call :init
rem ROS v7.4.0 by EA5HVK
call :check_running "ROS v7.4.0.exe"
If /I %RUNNING%==False  start "ROS" /D "C:\Program Files (x86)\ROS" /B /NORMAL "C:\Program Files (x86)\ROS\ROS v7.4.0.exe"
goto done

REM ------------ FSQcall --------------------
:6
call :check_running "FSQCALv042.exe"
If /I %RUNNING%==False (
	cd "C:\Users\J.Meiáburger\jmprogs\hamradio\FSQCALv042"
	start "FSQcall" /B /MIN /NORMAL "C:\Users\J.Meiáburger\jmprogs\hamradio\FSQCALv042\FSQCALv042.exe"
)
goto done

REM ------------ HRDLogbook only --------------------
:7
call :check_running "HRDLogbook.exe"
If /I %RUNNING%==False (
	start "HRDlog" /B /MIN /NORMAL "C:\Program Files (x86)\HRD Software, LLC\Ham Radio Deluxe\HRDLogbook.exe"
)
goto done

REM ----------- JS8Call -------------------
:8
call :init
call :check_running "js8call.exe"
If /I %RUNNING%==False (
	start "JS8Call" /D "C:\Program Files (x86)\wsjtx" /B /HIGH "C:\Program Files (x86)\js8call\bin\js8call.exe"
	timeout /t 3 /Nobreak
)
goto done

:init
REM ------------------------- start NTP client, USB sound card, HRD server and logbook  ---------------
REM --- NTP time synchronisation ---
call :check_running "BktTimeSync.exe"
If /I %RUNNING%==False start "BktTime" /B /NORMAL "C:\Program Files (x86)\BktTimeSync\BktTimeSyncStart.exe"

REM --- USB soundcard --- only for old IC706 !!
REM call :check_running "urouter.exe"
REM If /I %RUNNING%==False (
REM 	start "Urouter" /B /SEPARATE /REALTIME "C:\Program Files (x86)\microHAM\bin\urouter.exe"
REM 	timeout /t 2 /Nobreak
REM )

if "%mode%" EQU "5" goto Log
call :check_running "HamRadioDeluxe.exe"
If /I %RUNNING%==False (
	start "HRD" /B /MIN /NORMAL "C:\Program Files (x86)\HRD Software, LLC\Ham Radio Deluxe\HamRadioDeluxe.exe"
	timeout /t 6 /Nobreak
)

:Log
call :check_running "HRDLogbook.exe"
If /I %RUNNING%==False (
	start "HRDlog" /B /MIN /NORMAL "C:\Program Files (x86)\HRD Software, LLC\Ham Radio Deluxe\HRDLogbook.exe"
	timeout /t 2 /Nobreak
)
exit /B

REM ------------------------- check for already running processes -----------------------
:check_running
set RUNNING=False
set EXE=%~1
FOR /F %%x IN ('tasklist /NH /FI "IMAGENAME eq %EXE%"') DO IF %%x == %EXE% set RUNNING=True
echo "%EXE% running is %RUNNING%"
exit /B

REM kill running processes
:kill
call :kill_proc "js8call.exe"
call :kill_proc "easypal.exe"
call :kill_proc "Digital Master.exe"
call :kill_proc "wsjtx.exe"
call :kill_proc "JT9.exe"
call :kill_proc "JTAlert.exe"
call :kill_proc "JTPluginManager.exe"
call :kill_proc "HRDLogbook.exe"
call :kill_proc "HamRadioDeluxe.exe"
call :kill_proc "sim_psk.exe"
call :kill_proc "ROS v7.4.0.exe"
call :kill_proc "urouter.exe"
call :kill_proc "FSQCALv042.exe"
call :kill_proc "BktTimeSync.exe"
goto kill_done

:kill_proc
set "exe=%~1"
set "processFound="
for /f "tokens=5 delims=," %%a in ('
	tasklist /fi "imagename eq %exe%" /fo:csv /nh
') do set "processFound=1"

if defined processFound (
	taskkill /fi "imagename eq %exe%" /T /F
	echo %exe% has been killed!
   ) else (
	echo %exe% is NOT running
)
exit /B

REM ------------------ all done ----------------------
:done
rem --------------- start eQSL window for callsign lookup  ----------------------
rem start "" microsoft-edge:http://www.eqsl.cc/qslcard/Index.cfm
rem --- script to position and resize eqsl window
rem start "eQSL" /B /MIN /WAIT cscript start_eqsl.vbs /B

rem --- chrome frame keeps window size and position automatically !!
start "eQSL" /B /Separate "C:\Program Files (x86)\Google\Chrome\Application\chrome.exe" --chrome-frame  --app=http://www.eqsl.cc

:kill_done
timeout /t 10
rem pause
exit